; -------------------------------------------------------------------------------------------------------------------------------
;
; Author: Michael Reitz
; eMail: innosetup@assimilate.de
;
; This InnoSetup script shows how to install the Visual Basic Runtime files, DCOM and MDAC.
; You should go to the following webpages for dowloading the files and getting the most current information about the components:
; VB Runtime files: How-To Article on http://www.jrsoftware.org/ishowto.phtml?a=vb and http://msdn.microsoft.com/vstudio/
; DCOM: http://www.microsoft.com/com/dcom/dcom95/dcom1_3.asp and http://www.microsoft.com/com/dcom/dcom98/dcom1_3.asp
; MDAC: http://www.microsoft.com/data/
; Recommended release versions (October 2002):
; - Visual Basic 5.0 Sp3
; - Visual Basic 6.0 Sp5
; - DCOM 1.3
; - MDAC 2.5 Sp1/Sp2 (contains ADO 2.5, Microsoft Jet 4.0, OLE DB Providers for SQL-Server 7.0 / MSDE 1.0 and SQL-Server 6.5)
;	-> MDAC 2.5 is the version that comes with Windows 2000 SP1
;	-> MDAC 2.0 and above require DCOM on Windows 95 machines for installing successfully
;	-> There are some issues with existing Microsoft ODBC Driver for Access, version 3.51
; - MDAC 2.6 (contains ADO 2.6, OLE DB Provider for SQL-Server 2000)
;	-> MDAC 2.6 has some issues with SQL 7.0 or SQL 6.5 Clustered Servers
;	-> MDAC 2.6 doesn't contain Microsoft Jet drivers
; - MDAC 2.7 (contains ADO 2.7, same version that is shipped with Windows XP)
;   -> MDAC 2.7 is NOT SUPPORTED on Windows 95
;	-> MDAC 2.7 has some issues with SQL 7.0 or SQL 6.5 Clustered Servers
;	-> MDAC 2.7 doesn't contain Microsoft Jet drivers
;
; Comments:
; It may not be possible to install DCOM95 and MDAC in sequence (without a reboot between them) on Windows 95 systems,
; because Windows 95 comes without any DCOM version.
; Therefore MDAC is installed on Windows 95 systems by a HKCU\...\RunOnce registry entry after reboot, which requires
; that the same user (who executed the setup) logs in after the reboot for successfully installing MDAC.
; (It is not possible to use a HKLM\...\RunOnce entry, because there are timing problems with the after-reboot processes
;  of the DCOM installation.)
; The mdac_typ.exe file stays in the {%TEMP} folder after installation. If you want to prevent this, you should distribute
; mdac_typ.exe as external file and execute it from {src} (for example).
;
; Please remove and set comments in the [Registry] and [Run] sections depending on the distributed MDAC version, but always
; consider carefully which MDAC/ADO version your applications really requires and read the appropriate release manifest before
; distributing MDAC.
; -------------------------------------------------------------------------------------------------------------------------------

; This script was first created by ISTool
; http://www.bhenden.org/istool/

[Setup]
OutputDir=.
OutputBaseFilename=VB_DCOM_MDAC_Setup
AppName=VB - DCOM - MDAC
AppVerName=VB - DCOM - MDAC
MinVersion=4.0,4.0
AdminPrivilegesRequired=true
CreateAppDir=false
DisableProgramGroupPage=true
DisableStartupPrompt=true
Uninstallable=false

[Tasks]
Name: VB5RT; Description: Visual Basic Runtime 5.0; Flags: checkedonce
Name: VB6RT; Description: Visual Basic Runtime 6.0; Flags: checkedonce
Name: DCOM95; Description: DCOM 1.3 for Windows 95; Flags: checkedonce restart; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0
Name: DCOM98; Description: DCOM 1.3 for Windows 98; Flags: checkedonce; MinVersion: 4.1,0; OnlyBelowVersion: 4.9,0
Name: MDAC; Description: Microsoft Data Access Components; Flags: checkedonce restart; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0

[Files]
; START VISUAL BASIC
Source: Redist\VB_Runtime\STDOLE2.TLB; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regtypelib; Tasks: VB5RT VB6RT
Source: Redist\VB_Runtime\MSVBVM50.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver; Tasks: VB5RT
Source: Redist\VB_Runtime\MSVBVM60.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver; Tasks: VB6RT
Source: Redist\VB_Runtime\OleAut32.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver; Tasks: VB5RT VB6RT
Source: Redist\VB_Runtime\OlePro32.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver; Tasks: VB5RT VB6RT
Source: Redist\VB_Runtime\AsycFilt.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile; Tasks: VB5RT VB6RT
Source: Redist\VB_Runtime\ComCat.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver; Tasks: VB5RT VB6RT
; END VISUAL BASIC
; START DCOM
Source: Redist\DCOM\dcom95.EXE; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0; Tasks: DCOM95
Source: Redist\DCOM\dcom98.exe; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.1,0; OnlyBelowVersion: 4.9,0; Tasks: DCOM98
Source: Redist\DCOM\dcm95cfg.exe; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.0,0; OnlyBelowVersion: 4.9,0; Tasks: DCOM95 DCOM98
; END DCOM
; START MDAC
Source: Redist\MDAC\mdac_typ.exe; DestDir: {%TEMP}; CopyMode: alwaysoverwrite; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0; Tasks: MDAC
Source: Redist\MDAC\mdac_typ.exe; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.1,4.0; OnlyBelowVersion: 0,5.0; Tasks: MDAC
; END MDAC

[Registry]
; Delay MDAC installation on Win95 machines
;MDAC 2.0+
Root: HKCU; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce; ValueType: string; ValueName: MDAC_Setup; ValueData: """{%TEMP}\mdac_typ.exe"" /Q /C:""setup /QT"""; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0; Tasks: MDAC
;MDAC 2.6+
;Root: HKCU; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce; ValueType: string; ValueName: MDAC_Setup; ValueData: """{%TEMP}\mdac_typ.exe"" /Q:A /C:""dasetup /Q:D /N"""; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0; Tasks: MDAC

[Run]
; START DCOM
Filename: {tmp}\dcom95.EXE; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: DCOM95; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0
Filename: {tmp}\dcom98.exe; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: DCOM98; MinVersion: 4.1,0; OnlyBelowVersion: 4.9,0
Filename: {tmp}\dcm95cfg.exe; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: DCOM95 DCOM98; MinVersion: 4.0,0; OnlyBelowVersion: 4.9,0
; END DCOM
; START MDAC 2.0+ (see also: http://support.microsoft.com/default.aspx?scid=KB;EN-US;Q192009&)
Filename: {tmp}\mdac_typ.exe; Parameters: "/Q /C:""setup /QNT"""; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: MDAC; MinVersion: 4.1,4.0; OnlyBelowVersion: 0,5.0
; END MDAC 2.0+
; START MDAC 2.6+ (see also: http://msdn.microsoft.com/library/default.asp?url=/library/en-us/mdacsdk/htm/wphistory_redistributemdac.asp)
;Filename: {tmp}\mdac_typ.exe; Parameters: "/Q:A /C:""dasetup /Q:D /N"""; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: MDAC; MinVersion: 4.1,4.0; OnlyBelowVersion: 0,5.0
; END MDAC 2.6+